pipeline {
options {
  timeout(time: 5, unit: 'SECONDS')
  skipDefaultCheckout()
}

agent { label 'master' }
    stages {
        stage("Build Failure or Timeout") {
            steps {
                script {
                    build(
                      job: 'failing-job',
                      parameters: [],
                      propagate: true,
                      wait: true
                    )
                }
            }
            post {
              unsuccessful {
                script {
                    getInterruptionCause(currentBuild)
                }
              }
            }
        }
    }
}

def getInterruptionCause(def build)
{
  def directCause = null

  def rawBuild = build
  if (build instanceof org.jenkinsci.plugins.workflow.support.steps.build.RunWrapper) {
    rawBuild = build.getRawBuild()
  }

  def actions = rawBuild.getActions(jenkins.model.InterruptedBuildAction)
  for (action in actions) {
    def causes = action.getCauses()
    for (cause in causes) {

      // Print the causes and their root causes BFS style.
      println "Interruption Cause: " + cause.getShortDescription()
      directCause = cause

      // Received when the upstream build was cancelled.
      if(cause instanceof org.jenkinsci.plugins.workflow.support.steps.build.BuildTriggerCancelledCause) {
        def upstreamCause = build.getCause(hudson.model.Cause$UpstreamCause)
        if (upstreamCause) {
          getInterruptionCause(upstreamCause.getUpstreamRun())
        }
      }

      // Received when a job triggered a build that failed with propagate: true.
      if(cause instanceof org.jenkinsci.plugins.workflow.support.steps.build.DownstreamFailureCause) {
        getInterruptionCause(cause.getDownstreamBuild())
      }
    }
  }

  return directCause
}