stage('Test') {
    steps {
        script {
            def parallelTests = [:]
            def recipes = env.TESTED_RECIPES.split(',')
            def testSplit = env.TEST_SPLIT != null ? env.TEST_SPLIT.toInteger() : 1
            def testWebSplit = env.WEBTEST_SPLIT != null ? env.WEBTEST_SPLIT.toInteger() : 1
            for (def recipe in recipes) {
                for (def index = 1; index <= testSplit; ++index) {
                    parallelTests["Test JUnit $recipe $index/$testSplit"] = createTestExecutionStage('generic-test-junit', [
                        string(name: 'PIPELINE_ID', value: params.PIPELINE_ID),
                        string(name: 'RECIPE', value: recipe),
                        string(name: 'TEST_SPLIT_IDX', value: "${index}"),
                        string(name: 'TEST_SPLIT_MAX', value: "${testSplit}"),
                        string(name: 'PRIORITY', value: params.PRIORITY)
                    ])
                }
                for (def index = 1; index <= testWebSplit; ++index) {
                    parallelTests["Test Web JUnit $recipe $index/$testWebSplit"] = createTestExecutionStage('generic-test-junit', [
                        string(name: 'PIPELINE_ID', value: params.PIPELINE_ID),
                        string(name: 'RECIPE', value: recipe),
                        booleanParam(name: 'WEB_TESTS', value: true),
                        string(name: 'TEST_SPLIT_IDX', value: "${index}"),
                        string(name: 'TEST_SPLIT_MAX', value: "${testWebSplit}"),
                        string(name: 'PRIORITY', value: params.PRIORITY)
                    ], false)
                }
                parallelTests["Test Initialization $recipe"] = createTestExecutionStage('generic-test-initialization', [
                    string(name: 'PIPELINE_ID', value: params.PIPELINE_ID),
                    string(name: 'RECIPE', value: recipe),
                    string(name: 'PRIORITY', value: params.PRIORITY)
                ])
                parallelTests["Test Server $recipe"] = createTestExecutionStage('generic-test-server', [
                    string(name: 'PIPELINE_ID', value: params.PIPELINE_ID),
                    string(name: 'RECIPE', value: recipe),
                    string(name: 'PRIORITY', value: params.PRIORITY)
                ])
            }
            parallel parallelTests
        }
    }
}

def createTestExecutionStage(name, parameters, propagate = true) {
    return {
        build(job: name, parameters: parameters, propagate: propagate)
    }
}

pipelineJob('generic-test-junit') {
    displayName('Generic JUnit Test')
    description('''Multi-line description
is here''')

    logRotator {
        daysToKeep(90)
    }

    parameters {
        stringParam('PIPELINE_ID', '', 'Identifier of the pipeline which will be built.')
        stringParam('RECIPE', '', 'Recipe which will be tested.')
        booleanParam('WEB_TESTS', false, 'Defines whether web tests should be executed instead of the non-web tests.')
        stringParam('TEST_SPLIT_IDX', '', 'Index of the test package to be performed.')
        stringParam('TEST_SPLIT_MAX', '', 'Number of the test packages.')
        booleanParam('DEBUG', false, 'Defines whether test target should be executed in debug mode.')
        stringParam('PRIORITY', '', 'Pipeline priority (number from 1 to 5, where 1 is the highest).')
    }

    definition {
        cps {
            script(readFileFromWorkspace('jobs/genericTestJunit.jenkinsfile'))
            sandbox()
        }
    }
}

pipeline {
    agent {
        label 'swarm'
    }
    options {
        ansiColor('xterm')
    }
    stages {
        stage('Test') {
            steps {
                cleanWs()
                sh """#!/bin/bash
                    rsync -az jkmaster:build-scripts .
                    rsync -az jkmaster:resources/${params.PIPELINE_ID}/pipeline.properties .
                """
                script {
                    def environmentVariables = ""
                    readProperties(file: 'pipeline.properties')
                        .findAll { !params.containsKey(it.key) }
                        .each { k, v -> environmentVariables = "${environmentVariables}env.${k}='${v}'\n" }
                    writeFile file: 'env.groovy', text: environmentVariables
                }
                load 'env.groovy'
                script {
                    currentBuild.displayName = "#${env.BUILD_NUMBER}-${env.PRODUCT_NAME}-${params.PIPELINE_ID}-${params.RECIPE}-${params.WEB_TESTS ? 'WEB-' : ''}${params.TEST_SPLIT_IDX}-${params.TEST_SPLIT_MAX}"
                }

                timestamps {
                    lock(resource: null, label: 'rsync', quantity: 1) {
                        sh './build-scripts/synchronize-with-jkmaster.sh'
                    }
                }
                wrap([$class: 'LogfilesizecheckerWrapper', failBuild: true, maxLogSize: 0, setOwn: false]) {
                    wrap([$class: 'Xvfb', displayNameOffset: 2]) {
                        timestamps {
                            timeout(time: 6, unit: 'HOURS') {
                                timeout(time: 15, activity: true) {
                                    sh "./build-scripts/jobs/test-junit.sh ${params.WEB_TESTS ? 'web' : ''}"
                                }
                            }
                        }
                    }
                }
                junit 'junit/**/*.xml'
                archiveArtifacts artifacts: 'junit/**/*.xml'
            }
        }
    }
    post {
        always {
            cleanWs()
        }
    }
}