apply plugin: 'groovy'

ext {
    jobDslVersion = '1.78.3'
    jenkinsVersion = '2.332.2'
}

sourceSets {
    jobs {
        groovy {
            srcDirs 'jobdsl'
        }
    }
}

repositories {
    mavenCentral()
    maven {
        url 'https://repo.jenkins-ci.org/public/'
    }
}

configurations {
    testPlugins {}

    // see JENKINS-45512
    testImplementation {
        exclude group: 'xalan'
        exclude group: 'xerces'
    }
}

dependencies {
    // Groovy version:
    // Actually Jenkins currently uses Groovy 2.4.21 (Mange Jenkins > Script Console: "println GroovySystem.version")
    testImplementation 'org.spockframework:spock-core:1.3-groovy-2.4'

    // Jenkins test harness dependencies
    testImplementation 'org.jenkins-ci.main:jenkins-test-harness:1736.vc72c458c5103'
    testImplementation "org.jenkins-ci.main:jenkins-war:${jenkinsVersion}"

    // Job DSL plugin including plugin dependencies
    testImplementation "org.jenkins-ci.plugins:job-dsl:${jobDslVersion}"
    testImplementation "org.jenkins-ci.plugins:job-dsl:${jobDslVersion}@jar"
    testImplementation 'org.jenkins-ci.plugins:script-security:1145.vb_cf6cf6ed960@jar'
    testImplementation 'org.jenkins-ci.plugins:structs:308.v852b473a2b8c@jar'

    // plugins to install in test instance
    testPlugins 'org.jenkins-ci.plugins:cloudbees-folder:6.714.v79e858ef76a_2'
    testPlugins 'org.jenkins-ci.plugins:git:4.11.0' // TODO: leads to stderr warning logs "Failed Loading plugin"
    testPlugins 'org.jenkins-ci.plugins:matrix-auth:3.1'
    testPlugins 'org.jenkins-ci.plugins.workflow:workflow-cps:2660.vb_c0412dc4e6d' // TODO: should be:
    //testPlugins 'org.jenkins-ci.plugins.workflow:workflow-cps:2683.vd0a_8f6a_1c263'
    testPlugins 'org.jenkins-ci.plugins.workflow:workflow-job:1145.v7f2433caa07f' // TODO: should be:
    //testPlugins 'org.jenkins-ci.plugins.workflow:workflow-job:1174.vdcb_d054cf74a_'

}

task resolveTestPlugins(type: Copy) {
    from configurations.testPlugins
    into new File(sourceSets.test.output.resourcesDir, 'test-dependencies')
    include '*.hpi'
    include '*.jpi'

    //TODO: Rename files to fix stderr warning logs:
    //  WARNING	hudson.ClassicPluginStrategy#createPluginWrapper: encountered /tmp/jenkins851669878165500765/plugins/workflow-support-3.4.jpi under a nonstandard name; expected workflow-support.jpi
    // Debug logging:
    //eachFile { println it.file }
    // See maybe https://blog.mrhaki.com/2010/10/gradle-goodness-renaming-files-while.html

    doLast {
        def baseNames = source.collect { it.name[0..it.name.lastIndexOf('.')-1] }
        new File(destinationDir, 'index').setText(baseNames.join('\n'), 'UTF-8')
    }
}

test {
    dependsOn tasks.resolveTestPlugins
    inputs.files sourceSets.jobs.groovy.srcDirs

    // set build directory for Jenkins test harness, JENKINS-26331
    systemProperty 'buildDirectory', project.buildDir.absolutePath
}